利用 BAT 寫批次處理

批次處理的作用
簡單的說,批次處理的作用就是自動的連續執行多條指令。

這裡先講一個最簡單的套用:在啟動wps軟體時,每次都必須執行(>前面內容表示DOS提示號):
C:\>cd wps
C:\WPS>spdos
C:\WPS>py
C:\WPS>wbx
C:\WPS>wps
如果每次用WPS之前都這樣執行一遍,您是不是覺得很麻煩呢?

好了,用批次處理,就可以實現將這些麻煩的操作簡單化,首先我們編寫一個runwps.bat批次處理文件,內容如下:
@echo off
c:
cd\wps
spdos
py
wbx
wps
cd\

以後,我們每次進入wps,只需要執行runwps這個批次處理文件即可。

常用指令

echo、@、call、pause、rem(小技巧:用::替代rem)是批次處理文件最常用的幾個指令,我們就從他們開始學起。
echo 表示顯示此指令後的字元
echo off 表示在此語句後所有執行的指令都不顯示指令行本身
@與echo off相像,但它是加在每個指令行的最前面,表示執行時不顯示這一行的指令行(只能影響當前行)。
call 使用另一個批次處理文件(如果不用call而直接使用別的批次處理文件,那麼執行完那個批次處理文件後將無法返回當前文件並執行當前文件的後續指令)。
pause 執行此句會暫停批次處理的執行並在螢幕上顯示Press any key to continue...的提示,等待用戶按任意鍵後繼續
rem 表示此指令後的字元為解釋行(註釋),不執行,只是給自己今後參考用的(相當於程序中的註釋)。

例1:用edit編輯a.bat文件,輸入下列內容後儲存碟為c:\a.bat,執行該批次處理文件後可實現:將根目錄中所有文件寫入 a.txt中,啟動UCDOS,進入WPS等功能。

  批次處理文件的內容為:         指令註釋:

    @echo off           不顯示後續指令行及當前指令行
    dir c:\*.* >a.txt       將c碟文件列表寫入a.txt
    call c:\ucdos\ucdos.bat    使用ucdos
    echo 你好            顯示"你好"
    pause              暫停,等待按鍵繼續
    rem 準備執行wps         註釋:準備執行wps
    cd ucdos            進入ucdos目錄
    wps               執行wps  

批次處理文件的參數

批次處理文件還可以像C語言的函數一樣使用參數(相當於DOS指令的指令行參數),這需要用到一個參數表示符「%」。

%[1-9]表示參數,參數是指在執行批次處理文件時在檔案名後加的以空格(或者Tab)分隔的字元串。變數可以從%0到%9,%0表示批次處理指令本身,其它參數位符串用%1到%9順序表示。

例2:C:根目錄下有一批次處理檔案名為f.bat,內容為:
@echo off
format %1

如果執行C:\>f a:
那麼在執行f.bat時,%1就表示a:,這樣format %1就相當於format a:,於是上面的指令執行時實際執行的是format a:

例3:C:根目錄下一批次處理檔案名為t.bat,內容為:
@echo off
type %1
type %2

那麼執行C:\>t a.txt b.txt
%1 : 表示a.txt
%2 : 表示b.txt
於是上面的指令將順序地顯示a.txt和b.txt文件的內容。


特殊指令

if goto choice for是批次處理文件中比較進階的指令,如果這幾個你用得很熟練,你就是批次處理文件的專家啦。

一、if 是條件語句,用來判斷是否符合規定的條件,從而決定執行不同的指令。 有三種格式:

1、if [not] "參數" == "字元串" 待執行的指令

參數如果等於(not表示不等,下同)指定的字元串,則條件成立,執行指令,否則執行下一句。

例:if "%1"=="a" format a:

2、if [not] exist [路徑\]檔案名 待執行的指令
如果有指定的文件,則條件成立,執行指令,否則執行下一句。

如: if exist c:\config.sys type c:\config.sys
表示如果存在c:\config.sys文件,則顯示它的內容。

3、if errorlevel <數位> 待執行的指令

很多DOS程序在執行結束後會返回一個數位值用來表示程序執行的結果(或者狀態),通過if errorlevel指令可以判斷程序的返回值,根據不同的返回值來決定執行不同的指令(返回值必須按照從大到小的順序排列)。如果返回值等於指定的數位,則條件成立,執行指令,否則執行下一句。

如if errorlevel 2 goto x2

二、goto 批次處理文件執行到這裡將跳到goto所指定的標號(標號即label,標號用:後跟標準字元串來定義)處,goto語句一般與if配合使用,根據不同的條件來執行不同的指令組。

如:

goto end

:end
echo this is the end

標號用「:字元串」來定義,標號所在行不被執行。

三、choice 使用此指令可以讓用戶輸入一個字元(用於選項),從而根據用戶的選項返回不同的errorlevel,然後於if errorlevel配合,根據用戶的選項執行不同的指令。

注意:choice指令為DOS或者Windows系統提供的外部指令,不同版本的choice指令語法會稍有不同,請用choice /?檢視用法。

choice的指令語法(該語法為Windows 2003中choice指令的語法,其它版本的choice的指令語法與此大同小異):

CHOICE [/C choices] [/N] [/CS] [/T timeout /D choice] [/M text]

描述:
該工具允許用戶從選項列表選項一個項目並返回所選項目的索引。

參數列表:
/C choices 指定要新增的選項列表。預設列表是 "YN"。

/N 在提示號中隱藏選項列表。提示前面的消息得到顯示,
選項依舊處於啟用狀態。

/CS 允許選項分大小寫的選項。在預設情況下,這個工具
是不分大小寫的。

/T timeout 做出預設選項之前,暫停的秒數。可接受的值是從 0
到 9999。如果指定了 0,就不會有暫停,預設選項
會得到選項。

/D choice 在 nnnn 秒之後指定預設選項。字元必須在用 /C 選
項指定的一組選項中; 同時,必須用 /T 指定 nnnn。

/M text 指定提示之前要顯示的消息。如果沒有指定,工具只
顯示提示。

/? 顯示說明 消息。

注意:
ERRORLEVEL 環境變數被設定為從選項集選項的鍵索引。列出的第一個選
擇返回 1,第二個選項返回 2,等等。如果用戶按的鍵不是有效的選項,
該工具會發出警告響聲。如果該工具檢測到錯誤狀態,它會返回 255 的
ERRORLEVEL 值。如果用戶按 Ctrl+Break 或 Ctrl+C 鍵,該工具會返回 0
的 ERRORLEVEL 值。在一個批程序中使用 ERRORLEVEL 參數時,將參數降
序排列。

示例:
CHOICE /?
CHOICE /C YNC /M "驗證請按 Y,否請按 N,或者取消請按 C。"
CHOICE /T 10 /C ync /CS /D y
CHOICE /C ab /M "選項 1 請選項 a,選項 2 請選項 b。"
CHOICE /C ab /N /M "選項 1 請選項 a,選項 2 請選項 b。"

如果我執行指令:CHOICE /C YNC /M "驗證請按 Y,否請按 N,或者取消請按 C。"
螢幕上會顯示:
驗證請按 Y,否請按 N,或者取消請按 C。 [Y,N,C]?


例:test.bat的內容如下(注意,用if errorlevel判斷返回值時,要按返回值從高到低排列):
@echo off
choice /C dme /M "defrag,mem,end"
if errorlevel 3 goto end
if errorlevel 2 goto mem
if errotlevel 1 goto defrag

:defrag
c:\dos\defrag
goto end

:mem
mem
goto end

:end
echo good bye

此批次處理執行後,將顯示「defrag,mem,end[D,M,E]?」 ,用戶可選項d m e ,然後if語句根據用戶的選項作出判斷,d表示執行標號為defrag的程序段,m表示執行標號為mem的程序段,e表示執行標號為end的程序段,每個程序段最後都以goto end將程序跳到end標號處,然後程序將顯示good bye,批次處理執行結束。

四、for 循環指令,只要條件符合,它將多次執行同一指令。

語法:
對一組文件中的每一個文件執行某個特定指令。

FOR %%variable IN (set) DO command [command-parameters]

%%variable 指定一個單一字母可取代的參數。
(set) 指定一個或一組文件。可以使用萬用字元。
command 指定對每個文件執行的指令。
command-parameters
為特定指令指定參數或指令行開關。

例如一個批次處理文件中有一行:
for %%c in (*.bat *.txt) do type %%c

則該指令行會顯示當前目錄下所有以bat和txt為副檔名的文件的內容。


批次處理示例

1. IF-EXIST

1)

首先用記事本在C:\建立一個test1.bat批次處理文件,文件內容如下:
@echo off
IF EXIST \AUTOEXEC.BAT TYPE \AUTOEXEC.BAT
IF NOT EXIST \AUTOEXEC.BAT ECHO \AUTOEXEC.BAT does not exist

然後執行它:
C:\>TEST1.BAT

如果C:\存在AUTOEXEC.BAT文件,那麼它的內容就會被顯示出來,如果不存在,批次處理就會提示你該檔案不存在。

2)

接著再建立一個test2.bat文件,內容如下:
@ECHO OFF
IF EXIST \%1 TYPE \%1
IF NOT EXIST \%1 ECHO \%1 does not exist

執行:
C:\>TEST2 AUTOEXEC.BAT
該指令執行結果同上。

說明:
(1) IF EXIST 是用來測試文件是否存在的,格式為
IF EXIST [路徑+檔案名] 指令
(2) test2.bat文件中的%1是參數,DOS允許傳送9個批參數訊息給批次處理文件,分別為%1~%9(%0表示test2指令本身) ,這有點像編程中的實參和形參的關係,%1是形參,AUTOEXEC.BAT是實參。

3) 更進一步的,建立一個名為TEST3.BAT的文件,內容如下:
@echo off
IF "%1" == "A" ECHO XIAO
IF "%2" == "B" ECHO TIAN
IF "%3" == "C" ECHO XIN

如果執行:
C:\>TEST3 A B C
螢幕上會顯示:
XIAO
TIAN
XIN

如果執行:
C:\>TEST3 A B
螢幕上會顯示
XIAO
TIAN

在這個指令執行程序中,DOS會將一個空字元串指定給參數%3。

2、IF-ERRORLEVEL

建立TEST4.BAT,內容如下:
@ECHO OFF
XCOPY C:\AUTOEXEC.BAT D:IF ERRORLEVEL 1 ECHO 檔案拷貝失敗
IF ERRORLEVEL 0 ECHO 成功拷貝文件

然後執行文件:
C:\>TEST4

如果檔案拷貝成功,螢幕就會顯示「成功拷貝文件」,否則就會顯示「檔案拷貝失敗」。

IF ERRORLEVEL 是用來測試它的上一個DOS指令的返回值的,注意只是上一個指令的返回值,而且返回值必須依照從大到小次序順序判斷。
因此下面的批次處理文件是錯誤的:
@ECHO OFF
XCOPY C:\AUTOEXEC.BAT D:\
IF ERRORLEVEL 0 ECHO 成功拷貝文件
IF ERRORLEVEL 1 ECHO 未找到拷貝文件
IF ERRORLEVEL 2 ECHO 用戶通過ctrl-c中止拷貝操作
IF ERRORLEVEL 3 ECHO 預置錯誤阻止檔案拷貝操作
IF ERRORLEVEL 4 ECHO 拷貝程序中寫入磁碟錯誤

無論拷貝是否成功,後面的:

未找到拷貝文件
用戶通過ctrl-c中止拷貝操作
預置錯誤阻止檔案拷貝操作
拷貝程序中寫入磁碟錯誤

都將顯示出來。

以下就是幾個常用指令的返回值及其代表的意義:
backup
0 制作備份成功
1 未找到備份檔案
2 文件共享衝突阻止制作備份完成
3 用戶用ctrl-c中止制作備份
4 由於致命的錯誤使制作備份操作中止

diskcomp
0 盤比較相同
1 盤比較不同
2 用戶通過ctrl-c中止比較操作
3 由於致命的錯誤使比較操作中止
4 預置錯誤中止比較

diskcopy
0 盤拷貝操作成功
1 非致命盤讀/寫錯
2 用戶通過ctrl-c結束拷貝操作
3 因致命的處理錯誤使盤拷貝中止
4 預置錯誤阻止拷貝操作

format
0 格式化成功
3 用戶通過ctrl-c中止格式化處理
4 因致命的處理錯誤使格式化中止
5 在提示「proceed with format(y/n)?」下用戶按鍵輸入n結束

xcopy
0 成功拷貝文件
1 未找到拷貝文件
2 用戶通過ctrl-c中止拷貝操作
4 預置錯誤阻止檔案拷貝操作
5 拷貝程序中寫入磁碟錯誤

3、IF STRING1 == STRING2

建立TEST5.BAT,文件內容如下:
@echo off
IF "%1" == "A" FORMAT A:

執行:
C:\>TEST5 A
螢幕上就出現是否將A:盤格式化的內容。

注意:為了防止參數為空的情況,一般會將字元串用雙引號(或者其它符號,注意不能使用保留符號)括起來。
如:if [%1]==[A] 或者 if %1*==A*

5、GOTO

建立TEST6.BAT,文件內容如下:
@ECHO OFF
IF EXIST C:\AUTOEXEC.BAT GOTO _COPY
GOTO _DONE
:_COPY
COPY C:\AUTOEXEC.BAT D:\
:_DONE

注意:
(1) 標號前是ASCII字元的冒號":",冒號與標號之間不能有空格。
(2) 標號的命名規則與檔案名的命名規則相同。
(3) DOS支持最長八位字元的標號,當無法區別兩個標號時,將跳轉至最近的一個標號。

6、FOR

建立C:\TEST7.BAT,文件內容如下:
@ECHO OFF
FOR %%C IN (*.BAT *.TXT *.SYS) DO TYPE %%C

執行:
C:>TEST7

執行以後,螢幕上會將C:硬碟根目錄下所有以BAT、TXT、SYS為副檔名的文件內容顯示出來(不包括隱藏文件)。

留言

這個網誌中的熱門文章

c語言-關於#define用法

PHP教學 - 資料型態(Data Type) - 上

CMD常用網管指令